ꦫꦣꦺꦤ꧀ꦄꦤ꧀ꦠꦱꦺꦤ

PATH: usr / local / cpanel / scripts

#!/usr/local/cpanel/3rdparty/bin/perl

# cpanel - scripts/mailperm                        Copyright 2022 cPanel, L.L.C.
#                                                           All rights reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

package scripts::mailperm;

use strict;
use Digest::MD5  ();
use Getopt::Long ();
use IO::Handle   ();
use Try::Tiny;

use Cpanel::PwCache::Helpers             ();
use Cpanel::PwCache::Build               ();
use Cpanel::Exim                         ();
use Cpanel::Signal                       ();
use Cpanel::SafeFind                     ();
use Cpanel::Logger                       ();
use Cpanel::FileUtils::TouchFile         ();
use Cpanel::Rlimit                       ();
use Cpanel::AccessIds::ReducedPrivileges ();
use Cpanel::PwCache                      ();
use Cpanel::Config::LoadUserDomains      ();
use Cpanel::ConfigFiles                  ();
use Cpanel::Email::MX                    ();
use Cpanel::Email::Perms                 ();
use Cpanel::Email::Perms::System         ();
use Cpanel::Email::Perms::User           ();
use Cpanel::MailTools::DBS               ();
use Cpanel::LoginDefs                    ();
use Cpanel::Config::LoadConfig           ();

my $logger = Cpanel::Logger->new();

my @MAILDIR_FILES_TO_SKIP = qw(
  courierimapkeywords
  courierimapuiddb
  courierpop3dsizelist
  dovecot-keywords
  dovecot-uidlist
  dovecot-uidvalidity.*
  dovecot\\.index
  dovecot\\.index.cache
  dovecot\\.index.log
  dovecot\\.index.log.2
  maildirsize
  subscriptions
);
my $maildir_files_to_skip_re = join '|', @MAILDIR_FILES_TO_SKIP;

exit main(@ARGV) unless caller;

sub main {
    my (@args) = @_;
    local $@;

my $verbose           = 0;
    my $skiplocal         = 0;
    my $skipmxcheck       = 0;
    my $skipperm          = 0;
    my $dirsonly          = 0;
    my $no_restart_cpsrvd = 0;
    my $help              = 0;

# Argument processing
    my %arg_ops = (
        'help'              => \$help,
        'verbose'           => \$verbose,
        'skiplocaldomains'  => \$skiplocal,
        'skipmxcheck'       => \$skipmxcheck,
        'skipserverperm'    => \$skipperm,
        'dirsonly'          => \$dirsonly,
        'no-restart-cpsrvd' => \$no_restart_cpsrvd,
    );

Getopt::Long::GetOptionsFromArray(
        \@args,
        %arg_ops,
    ) or return _usage(1);
    return _usage(0) if $help;

my %opts = map { $_ => ${ $arg_ops{$_} } } keys %arg_ops;

if (@args) {
        $opts{'checkuser'} = $args[-1];
    }

my ( $status, $message ) = eval { __PACKAGE__->script(%opts) };

if ($@) {
        print "$@\n";
        return 1;
    }

return 0 if $status;

if ($message) {
        print STDERR $message . "\n";
    }

return 1;
}

sub script {
    my ( $class, %OPTS ) = @_;

my ( $checkuser, $skiplocal, $skipmxcheck, $skipperm, $dirsonly, $verbose ) = @OPTS{qw( checkuser skiplocaldomains skipmxcheck skipserverperm dirsonly verbose)};

return 1 if ( $ENV{'DONT_RUN_MAILPERM'} );

Cpanel::Rlimit::set_rlimit();

my $pidfile = '/var/run/mailperms.pid';

my $is_global             = 0;
    my $previous_command_name = $0;
    if ($checkuser) {
        if ( !( Cpanel::PwCache::getpwnam($checkuser) )[0] ) {
            warn "!! Specified user is not a valid system account !!\n\n";
            _usage();
            return ( 0, "The specified user '$checkuser' is not a valid system account" );
        }
        $0 = 'mailperm - single user';
    }
    else {
        $is_global = 1;
        $0         = 'mailperm - global';

require Cpanel::Unix::PID::Tiny;
        my $upid = Cpanel::Unix::PID::Tiny->new();

if ( !$upid->pid_file($pidfile) ) {
            my $pid = $upid->get_pid_from_pidfile($pidfile);
            $logger->warn("mailperm - previous instance: [$pid]");
            $0 = $previous_command_name;
            return ( 0, 'Another mailperm instance is running' );
        }
    }

my ( $exim_bin, $exim_version, $exim_caps ) = Cpanel::Exim::fetch_caps();
    my $needs_mail_gid_shadow = ( $exim_caps->{'dovecot'} ) ? 0 : 1;
    $Cpanel::Email::Perms::VERBOSE = $verbose;
    my $changed_external_auth = 0;

# Signal cpsrvd to reload its config.
    # do not restart cpsrvd on a fresh install ( cpsrvd is running but is restarted later )
    #   this avoids to solve continuously "perl dependencies issues" in the exim rpm
    Cpanel::Signal::send_hup_cpsrvd() if $changed_external_auth && !$OPTS{'no-restart-cpsrvd'};

Cpanel::Email::Perms::System::ensure_system_perms();

if ( !$skipperm ) {
        require '/usr/local/cpanel/scripts/checkexim.pl';    ## no critic qw(RequireBarewordIncludes)
        scripts::checkexim::checkeximperms();
    }

chmod( 0666, '/dev/null' );

_update_local_domains( 'checkuser' => $checkuser, 'skipmxcheck' => $skipmxcheck, 'verbose' => $verbose ) if !$skiplocal;

_set_perms( 'checkuser' => $checkuser, 'dirsonly' => $dirsonly, 'verbose' => $verbose, 'is_global' => $is_global ) if !$skipperm;

chmod( 0666, '/dev/null' );

$0 = $previous_command_name;

return 1;
}

sub _update_local_domains {
    my (%OPTS) = @_;

my ( $checkuser, $skipmxcheck, $verbose ) = @OPTS{qw( checkuser skipmxcheck verbose )};

Cpanel::FileUtils::TouchFile::touchfile($Cpanel::ConfigFiles::REMOTEDOMAINS_FILE);
    Cpanel::FileUtils::TouchFile::touchfile($Cpanel::ConfigFiles::LOCALDOMAINS_FILE);

my $localdomains_ref  = Cpanel::Config::LoadConfig::loadConfig( $Cpanel::ConfigFiles::LOCALDOMAINS_FILE,  undef, '' );
    my $remotedomains_ref = Cpanel::Config::LoadConfig::loadConfig( $Cpanel::ConfigFiles::REMOTEDOMAINS_FILE, undef, '' );
    my $secondarymx_ref   = Cpanel::Config::LoadConfig::loadConfig( $Cpanel::ConfigFiles::SECONDARYMX_FILE,   undef, '' );

my $userdomains_ref = Cpanel::Config::LoadUserDomains::loaduserdomains( undef, 1 );
    my %missing_domains;

require Cpanel::Hostname;
    my $hostname = Cpanel::Hostname::gethostname();
    $userdomains_ref->{$hostname} = 1;

foreach my $domain ( keys %{$userdomains_ref} ) {
        if ( !exists $localdomains_ref->{$domain} && !exists $remotedomains_ref->{$domain} ) {
            $missing_domains{$domain} = 1;
        }
    }

if ( !$skipmxcheck ) {
        require Whostmgr::DNS::MX;
        foreach my $domain ( sort keys %{$userdomains_ref} ) {
            next if ( $domain =~ m/^\*/ );

my $user = $userdomains_ref->{$domain};
            next if ( !$user || $user eq 'root' || ( $checkuser && $checkuser ne $user ) );

print "Checking mx configuration for $domain ($user)..." if $verbose;
            my $alwaysaccept = Cpanel::Email::MX::get_mxcheck_configuration( $domain, $user );
            print "[$alwaysaccept]..." if $verbose;

#
            # We need to update proxysubdomains here because nothing else
            # will be doing it for us
            #
            if ( $alwaysaccept eq 'local'
                && ( !exists $localdomains_ref->{$domain} || exists $remotedomains_ref->{$domain} || exists $secondarymx_ref->{$domain} ) ) {
                Cpanel::MailTools::DBS::setup( $domain, 'localdomains' => 1, 'remotedomains' => 0, 'secondarymx' => 0, 'update_proxy_subdomains' => 1 );
            }
            elsif (( $alwaysaccept eq 'secondary' || $alwaysaccept eq 'backup' )
                && ( exists $localdomains_ref->{$domain} || !exists $remotedomains_ref->{$domain} || !exists $secondarymx_ref->{$domain} ) ) {
                Cpanel::MailTools::DBS::setup( $domain, 'localdomains' => 0, 'remotedomains' => 1, 'secondarymx' => 1, 'update_proxy_subdomains' => 1 );
            }
            elsif ( $alwaysaccept eq 'remote'
                && ( exists $localdomains_ref->{$domain} || !exists $remotedomains_ref->{$domain} || exists $secondarymx_ref->{$domain} ) ) {
                Cpanel::MailTools::DBS::setup( $domain, 'localdomains' => 0, 'remotedomains' => 1, 'secondarymx' => 0, 'update_proxy_subdomains' => 1 );
            }
            elsif ( $missing_domains{$domain} ) {
                {
                    no warnings 'once';
                    my $checkmx = Whostmgr::DNS::MX::checkmx( $domain, undef, $alwaysaccept, $Whostmgr::DNS::MX::NO_UPDATEUSERDOMAINS, $Whostmgr::DNS::MX::DO_UPDATE_PROXY_SUBDOMAINS );
                }
            }
            print "Done\n" if $verbose;
        }
    }
    else {
        foreach my $domain ( keys %missing_domains ) {
            Cpanel::MailTools::DBS::setup( $domain, 'localdomains' => 1, 'remotedomains' => 0, 'secondarymx' => 0, 'update_proxy_subdomains' => 1 );
        }
    }

return;
}

sub _set_perms {    ## no critic (Subroutines::ProhibitExcessComplexity)
    my (%OPTS) = @_;

my $checkuser = $OPTS{'checkuser'};
    my $dirsonly  = $OPTS{'dirsonly'} ? 1 : 0;
    my $verbose   = $OPTS{'verbose'}  ? 1 : 0;
    my $is_global = $OPTS{'is_global'} || 0;

my $mailgid = ( Cpanel::PwCache::getpwnam('mail') )[3];

my $pwcache_ref;
    if ($checkuser) {
        my @pw_data = Cpanel::PwCache::getpwnam($checkuser);
        $pwcache_ref = [ \@pw_data ];
    }
    else {
        Cpanel::PwCache::Build::init_passwdless_pwcache();
        Cpanel::PwCache::Helpers::no_uid_cache();    #uid cache only needed if we are going to make lots of getpwuid calls
        $pwcache_ref = Cpanel::PwCache::Build::fetch_pwcache();
    }

Cpanel::SafeFind::find( sub { }, '/dev/null' );    #init File::Find

my $userdomains_ref = Cpanel::Config::LoadUserDomains::loaduserdomains( undef, 0, 1 );

my $uid_min = Cpanel::LoginDefs::get_uid_min();
    my ( $cpuser, $useruid, $usergid, $homedir );
    foreach my $pwref ( sort { $a->[0] cmp $b->[0] } grep { exists $userdomains_ref->{ $_->[0] } && $_->[2] >= $uid_min } @$pwcache_ref ) {
        ( $cpuser, $useruid, $usergid, $homedir ) = ( (@$pwref)[ 0, 2, 3, 7 ] );
        next if ( $checkuser && $cpuser ne $checkuser );

if ( !$useruid || !$usergid || !$homedir ) {
            warn "Skipping invalid user $cpuser";
            next;
        }

if ( exists $userdomains_ref->{$cpuser} ) {
            foreach my $domain ( @{ $userdomains_ref->{$cpuser} } ) {
                Cpanel::Email::Perms::System::ensure_domain_system_perms( $useruid, $domain );
            }
        }
        if ( -e "$homedir/mail" || -e "$homedir/etc" ) {

Cpanel::AccessIds::ReducedPrivileges::call_as_user(
                sub {
                    local $0 = 'mailperm - ' . ( $is_global ? 'global ' : '' ) . 'processing ' . $cpuser;

my ( $mode, $fuid, $fgid, $safefile );
                    Cpanel::SafeFind::find(
                        {
                            'wanted' => sub {
                                return if ( !$File::Find::name || -l $File::Find::name );

( $mode, $fuid, $fgid ) = ( stat(_) )[ 2, 4, 5 ];
                                ($safefile) = $File::Find::name =~ /(.*)/;
                                if ( $fuid != $useruid || ( $fgid != $usergid && $fgid != $mailgid ) ) {
                                    my $changed = chown( $useruid, $usergid, $safefile );
                                    if ($verbose) {
                                        if ($changed) {
                                            print "Fixed ownership on $File::Find::name: was ($fuid:$fgid), now ($useruid:$usergid)\n";
                                        }
                                        else {
                                            print "Unable to fix ownership on $File::Find::name: currently ($fuid:$fgid), should be ($useruid:$usergid)\n";
                                        }
                                    }
                                }
                                return
                                  if ( $File::Find::name =~ m/\/(?:$maildir_files_to_skip_re)$/
                                    || $File::Find::name =~ m/\.cppop\.cache(?:\.msgs)?$/ );

( $mode, my $want ) = map { sprintf '%04o', $_ & 07777 } $mode, $Cpanel::Email::Perms::MAILDIR_PERMS;
                                if ( -d _ ) {

# All dirs must now be 0751 with dovecot 2.2.
                                    # in order to avoid:
                                    #   "Renaming not supported across conflicting directory permissions."
                                    if ( $mode ne $want ) {    #all of these are ok
                                        my $changed = chmod( $Cpanel::Email::Perms::MAILDIR_PERMS, $safefile );
                                        if ($verbose) {
                                            if ($changed) {
                                                print "Fixed permissions on $File::Find::name : was ($mode), now ($want)\n";
                                            }
                                            else {
                                                print "Unable to fix permissions on $File::Find::name : currently ($mode), should be ($want)\n";
                                            }
                                        }
                                    }

if ( $dirsonly && $safefile =~ m{\/\.[^\/]+\/[^\/]+$} ) {
                                        no warnings 'once';
                                        return ( $File::Find::prune = 1 );
                                    }
                                    return;
                                }

#NOTE: Until 11.54 this was 0660. Cobra
                                #couldn’t think of any reason why anyone
                                #but the user should be modifying the home
                                #directory, though, so we changed it to 0640.
                                #
                                elsif ( !$dirsonly && $mode ne '0640' ) {
                                    my $changed = chmod( 0640, $safefile );
                                    if ($verbose) {
                                        if ($changed) {
                                            print "Fixed permissions on $File::Find::name: was ($mode), now (0640)\n";
                                        }
                                        else {
                                            print "Unable to fix permissions on $File::Find::name: currently ($mode), should be (0640)\n";
                                        }
                                    }
                                }
                            },
                            'follow'   => 0,
                            'no_chdir' => 1
                        },
                        $homedir . '/mail'
                    );

return 1;
                },

$useruid,
                $usergid,
                $mailgid
              )
              || do {
                warn "Could not setuid to $cpuser ($useruid,$usergid + $mailgid)";
              };

try {
                Cpanel::Email::Perms::User::ensure_all_perms($homedir);
            }
            catch {
                warn $_;
            };
        }
        else {
            print "Skipping $homedir (etc and mail missing)\n";
        }
    }
    return;
}

sub _usage {
    my ($retval) = @_;
    my $fh = $retval ? \*STDERR : \*STDOUT;
    $fh->print(<<'EOM');
Usage: mailperm <modifier> <user>

Arguments:
    <user> - Optional argument to specify the scope of
        the permissions checks. The specified user must
        be a valid system account.

Modifier Flags:
    --skiplocaldomains - This optional argument bypasses
        addition of missing domains to the /etc/localdomains
        file when specified. The localdomains file specifies
        to Exim that it should always accept delivery for
        the listed domains. Remote domains are removed from
        /etc/localdomains regardless of this flag.

--skipmxcheck - This optional argument bypasses synchronizing
        the mail exchanger setting from the cpanel users file to the
        system.

--dirsonly - This optional flag limits setting permissions
        to only modifying directories.
        NOTE: The “maildirsize” files are always fixed if needed.

--skipserverperm - This optional flag prevents modification
        of the mail system files used by Exim and limits the
        scope of permission modifications to the mail account
        files.

--verbose - This optional flag signals the utility to
        report detected permissions problems per user prior
        to modifying any permissions.

--help - display this message and exit.

EOM
    return $retval;
}

[+] ..
[-] rebuild_whm_chrome [edit]
[-] check_mail_spamassassin_compiledregexps_body_0 [edit]
[-] transfer_accounts_as_root [edit]
[-] cphulkdblacklist [edit]
[-] fixquotas [edit]
[-] archive_sync_zones [edit]
[-] listsubdomains [edit]
[-] suspendmysqlusers [edit]
[-] userdata_wildcard_cleanup [edit]
[-] perlinstaller [edit]
[-] mkwwwacctconf [edit]
[-] realrawchpass [edit]
[-] find_pids_with_inotify_watch_on_path [edit]
[-] update_mysql_systemd_config [edit]
[-] oopscheck [edit]
[-] hackcheck [edit]
[-] spamboxdisable [edit]
[-] check_cpanel_pkgs [edit]
[-] installpkg [edit]
[-] removeacct [edit]
[-] initsuexec [edit]
[-] checkalldomainsmxs [edit]
[-] mainipcheck [edit]
[-] restartsrv_nscd [edit]
[-] cleandns8 [edit]
[-] quickwhoisips [edit]
[-] make_hostname_unowned [edit]
[-] perform_sqlite_auto_rebuild_db_maintenance [edit]
[-] fix_pear_registry [edit]
[-] importmydnsdb [edit]
[-] builddovecotconf [edit]
[-] check_valid_server_hostname [edit]
[-] cphulkdwhitelist [edit]
[-] verify_vhost_includes [edit]
[-] make_config [edit]
[-] compilerscheck [edit]
[-] apachelimits [edit]
[-] restartsrv_unknown [edit]
[-] purge_old_config_caches [edit]
[-] checkbashshell [edit]
[-] cpbackup_transport_file [edit]
[-] check_unmonitored_enabled_services [edit]
[-] wwwacct [edit]
[-] listcheck [edit]
[-] sync_child_accounts [edit]
[-] ensure_includes [edit]
[-] fix_addon_permissions [edit]
[-] update_spamassassin_config [edit]
[-] fixmailinglistperms [edit]
[-] fixwebalizer [edit]
[-] restartsrv_xinetd [edit]
[-] gensysinfo [edit]
[-] buildeximconf [edit]
[-] resetquotas [edit]
[-] restartsrv_base [edit]
[-] disable_sqloptimizer [edit]
[-] configure_rh_ipv6_firewall_for_cpanel [edit]
[-] securerailsapps [edit]
[-] unlink_service_account [edit]
[-] resetmailmanurls [edit]
[-] locale_export [edit]
[-] dovecot_set_defaults.pl [edit]
[-] updatenow [edit]
[-] run_plugin_lifecycle [edit]
[-] set_php_memory_limits [edit]
[-] linksubemailtomainacct [edit]
[-] increase_filesystem_limits [edit]
[-] restartsrv_cpanel_php_fpm [edit]
[-] try-later [edit]
[-] restartsrv [edit]
[-] addpop [edit]
[-] upcp [edit]
[-] export_horde_contacts_to_vcf [edit]
[-] restorecpuserfromcache [edit]
[-] perlmods [edit]
[-] upcp-running [edit]
[-] modify_accounts [edit]
[-] restartsrv_cpanalyticsd [edit]
[-] restartsrv_cpanellogd [edit]
[-] cleansessions [edit]
[-] delpop [edit]
[-] sync_contact_emails_to_cpanel_users_files [edit]
[-] addsystemuser [edit]
[-] migrate_whmtheme_file_to_userdata [edit]
[-] rebuildinstalledssldb [edit]
[-] whoowns [edit]
[-] fix-cpanel-perl [edit]
[-] editquota [edit]
[-] setpostgresconfig [edit]
[-] killpvhost [edit]
[-] check_users_my_cnf [edit]
[-] check_domain_tls_service_domains.pl [edit]
[-] restorepkg [edit]
[-] cpdig [edit]
[-] maintenance [edit]
[-] securetmp [edit]
[-] restartsrv_clamd [edit]
[-] expunge_expired_certificates_from_sslstorage [edit]
[-] updatenameserverips [edit]
[-] runstatsonce [edit]
[-] restartsrv_pdns [edit]
[-] unsuspendmysqlusers [edit]
[-] named.rfc1912.zones [edit]
[-] update_dkim_keys [edit]
[-] restartsrv_tailwatchd [edit]
[-] restartsrv_cpipv6 [edit]
[-] realadduser [edit]
[-] rebuildippool [edit]
[-] dav_change_hostname [edit]
[-] restartsrv_ftpd [edit]
[-] rpmup [edit]
[-] post_snapshot [edit]
[-] gencrt [edit]
[-] xferpoint [edit]
[-] convert_and_migrate_from_legacy_backup [edit]
[-] transfermysqlusers [edit]
[-] unslavenamedconf [edit]
[-] comparecdb [edit]
[-] email_hold_maintenance [edit]
[-] userdirctl [edit]
[-] install_dovecot_fts [edit]
[-] grpck [edit]
[-] ensure_hostname_resolves [edit]
[-] set_mailman_archive_perms [edit]
[-] check_cpanel_rpms [edit]
[-] sshcontrol [edit]
[-] check_security_advice_changes [edit]
[-] fastmail [edit]
[-] fixnamedviews [edit]
[+] cpan_sandbox
[-] eximstats_spam_check [edit]
[-] updatessldomains [edit]
[-] restartsrv_ftpserver [edit]
[-] post_sync_cleanup [edit]
[-] restartsrv_rsyslog [edit]
[-] proxydomains [edit]
[-] patch_mail_spamassassin_compiledregexps_body_0 [edit]
[-] convert_accesshash_to_token [edit]
[-] nixstatsagent.sh [edit]
[-] restartsrv_exim [edit]
[-] check_mount_procfs [edit]
[-] rebuildnsdzones [edit]
[-] killspamkeys [edit]
[-] ckillall [edit]
[-] check_maxmem_against_domains_count [edit]
[-] pwck [edit]
[-] uninstall_cpanel_analytics [edit]
[-] cpservice [edit]
[-] remote_log_transfer [edit]
[-] initquotas [edit]
[-] wwwacct2 [edit]
[-] refresh-dkim-validity-cache [edit]
[-] spamassassindisable [edit]
[-] rsync-user-homedir.pl [edit]
[-] dnscluster [edit]
[-] convert2dovecot [edit]
[-] installpostgres [edit]
[-] copy_user_mail_as_root [edit]
[-] rebuild_provider_openid_connect_links_db [edit]
[-] fixrndc [edit]
[-] restartsrv_sshd [edit]
[-] enable_spf_dkim_globally [edit]
[-] restartsrv_syslogd [edit]
[-] killdns [edit]
[-] dcpumon-wrapper [edit]
[-] dumpstor [edit]
[-] ptycheck [edit]
[-] initfpsuexec [edit]
[-] updatesigningkey [edit]
[-] update_local_rpm_versions [edit]
[-] expunge_expired_transfer_sessions [edit]
[-] find_outdated_services [edit]
[-] ipusage [edit]
[-] check_unreliable_resolvers [edit]
[-] restartsrv_pop3 [edit]
[-] restartsrv_postgresql [edit]
[-] restartsrv_dnsadmin [edit]
[-] vps_optimizer [edit]
[-] email_archive_maintenance [edit]
[-] ensure_crontab_permissions [edit]
[-] buildhttpdconf [edit]
[-] cpanpingtest [edit]
[-] build_mail_sni [edit]
[-] get_locale_from_legacy_name_info [edit]
[-] fixrelayd [edit]
[-] gemwrapper [edit]
[-] snapshot_prep [edit]
[-] restartsrv_p0f [edit]
[-] test_sa_compiled [edit]
[-] gather_update_logs_setupcrontab [edit]
[-] installsqlite3 [edit]
[-] autorepair [edit]
[-] featuremod [edit]
[-] vzzo-fixer [edit]
[-] mysqlpasswd [edit]
[-] ssl_crt_status [edit]
[-] mailperm [edit]
[-] restartsrv_named [edit]
[-] build_bandwidthdb_root_cache_in_background [edit]
[-] backups_clean_metadata_for_missing_backups [edit]
[-] realperlinstaller [edit]
[-] update-packages [edit]
[-] ftpfetch [edit]
[-] ftpsfetch [edit]
[-] import_exim_data [edit]
[-] restartsrv_cphulkd [edit]
[-] unsuspendacct [edit]
[-] setup_greylist_db [edit]
[-] setupmailserver [edit]
[-] maildir_converter [edit]
[-] fixtar [edit]
[-] cleanphpsessions.php [edit]
[-] restartsrv_lmtp [edit]
[-] getremotecpmove [edit]
[-] biglogcheck [edit]
[-] chkpaths [edit]
[-] litespeed-check [edit]
[-] quota_auto_fix [edit]
[-] generate_account_suspension_include [edit]
[-] fixvaliases [edit]
[-] checknsddirs [edit]
[-] synctransfers [edit]
[-] upgrade_bandwidth_dbs [edit]
[-] phpini_tidy [edit]
[-] cleanupmysqlprivs [edit]
[-] restartsrv_imap [edit]
[-] killdns-dnsadmin [edit]
[-] ccs-check [edit]
[-] spamassassin_dbm_cleaner [edit]
[-] process_pending_cpanel_php_pear_registration [edit]
[-] setup_modsec_db [edit]
[-] restartsrv_cpsrvd [edit]
[-] enable_sqloptimizer [edit]
[-] slurp_exim_mainlog [edit]
[-] balance_linked_node_quotas [edit]
[-] smartcheck [edit]
[-] smtpmailgidonly [edit]
[-] notify_expiring_certificates [edit]
[-] pedquota [edit]
[-] syslog_check [edit]
[-] killmysqlwildcard [edit]
[-] fetchfile [edit]
[-] setup_systemd_timer_for_plugins [edit]
[-] postupcp [edit]
[-] mailscannerupdate [edit]
[-] MirrorSearch_pingtest [edit]
[-] cpbackup [edit]
[-] named.ca [edit]
[-] build_cpnat [edit]
[-] cpanelsync [edit]
[-] mysqlconnectioncheck [edit]
[-] ensure_dovecot_memory_limits_meet_minimum [edit]
[-] checkccompiler [edit]
[-] zoneexists [edit]
[-] fixheaders [edit]
[-] validate_sshkey_passphrase [edit]
[-] rawchpass [edit]
[-] compilers [edit]
[-] update_exim_rejects [edit]
[+] php_sandbox
[-] restartsrv_crond [edit]
[-] cpaddonsup [edit]
[-] create_default_featurelist [edit]
[-] rebuild_dbmap [edit]
[-] restartsrv_mysql [edit]
[-] servicedomains [edit]
[-] dnsqueuecron [edit]
[-] build_maxemails_config [edit]
[-] install_plugin [edit]
[-] expunge_expired_pkgacct_sessions [edit]
[-] cleanupinterchange [edit]
[-] manage_extra_marketing [edit]
[-] find_and_fix_rpm_issues [edit]
[-] rebuild_available_rpm_addons_cache [edit]
[-] httpspamdetect [edit]
[-] restartsrv_apache [edit]
[-] restartsrv_mydns [edit]
[-] convert_whmxfer_to_sqlite [edit]
[-] jetbackup-check [edit]
[-] dumpcdb [edit]
[-] clear_cpaddon_ui_caches [edit]
[-] update_users_vhosts [edit]
[-] rebuildhttpdconf [edit]
[-] generate_maildirsize [edit]
[-] modify_packages [edit]
[-] checkusers [edit]
[-] generate_google_drive_oauth_uri [edit]
[-] fix-listen-on-localhost [edit]
[-] exportmydnsdb [edit]
[-] update_apachectl [edit]
[-] fixndc [edit]
[-] sendicq [edit]
[-] restartsrv_nsd [edit]
[-] restartsrv_apache_php_fpm [edit]
[-] cleanphpsessions [edit]
[-] clear_orphaned_virtfs_mounts [edit]
[-] check_immutable_files [edit]
[-] rebuild_available_addons_packages_cache [edit]
[-] restartsrv_queueprocd [edit]
[-] updateuserdomains [edit]
[-] clean_dead_mailman_locks [edit]
[-] magicloader [edit]
[-] restartsrv_bind [edit]
[-] update_existing_mail_quotas_for_account [edit]
[-] ensure_autoenabled_features [edit]
[-] fix_dns_zone_ttls [edit]
[-] unblockip [edit]
[-] dovecot_maintenance [edit]
[-] reset_mail_quotas_to_sane_values [edit]
[-] cpfetch [edit]
[-] restartsrv_ipaliases [edit]
[-] convert_mdbox_to_maildir [edit]
[-] cpuser_service_manager [edit]
[-] exim_tidydb [edit]
[-] upcp.static [edit]
[-] restartsrv_rsyslogd [edit]
[-] locale_info [edit]
[-] convert_roundcube_mysql2sqlite [edit]
[-] transfer_in_progress.pod [edit]
[-] modsec_vendor [edit]
[-] backups_list_user_files [edit]
[-] upgrade_subaccount_databases [edit]
[-] sysup [edit]
[-] synccpaddonswithsqlhost [edit]
[-] simpleps [edit]
[-] update_sa_config [edit]
[-] restartsrv_cpdavd [edit]
[-] enablefileprotect [edit]
[-] restartsrv_spamd [edit]
[-] distro_changed_hook [edit]
[-] install_cpanel_analytics [edit]
[-] restartsrv_inetd [edit]
[-] run_if_exists [edit]
[-] convert_to_dovecot_delivery [edit]
[-] clean_up_temp_wheel_users [edit]
[-] fix_reseller_acls [edit]
[-] update_mailman_cache [edit]
[-] killmysqluserprivs [edit]
[-] restartsrv_dovecot [edit]
[-] transfer_account_as_user [edit]
[-] restartsrv_proftpd [edit]
[-] generate_google_drive_credentials [edit]
[-] hook [edit]
[-] clean_user_php_sessions [edit]
[-] restartsrv_pureftpd [edit]
[-] wpt_license [edit]
[-] logo.dat [edit]
[-] isdedicatedip [edit]
[-] dumpinodes [edit]
[-] ftpupdate [edit]
[-] rdate [edit]
[-] backups_create_metadata [edit]
[-] link_3rdparty_binaries [edit]
[-] check_mysql [edit]
[-] checkexim.pl [edit]
[-] quickdnslookup [edit]
[-] updatenow.static [edit]
[-] transfer_in_progress [edit]
[-] runweblogs [edit]
[-] unpkgacct [edit]
[-] cpanelsync_postprocessor [edit]
[-] xfer_rcube_uid_resolver.pl [edit]
[-] export_horde_calendars_to_ics [edit]
[-] update_users_jail [edit]
[-] fixetchosts [edit]
[-] hulk-unban-ip [edit]
[-] custom_backup_destination.pl.sample [edit]
[-] restartsrv_mailman [edit]
[-] checklink [edit]
[-] add_dns [edit]
[-] fixtlsversions [edit]
[-] realchpass [edit]
[-] quotacheck [edit]
[-] copy_user_mail_as_user [edit]
[-] cleandns [edit]
[-] restartsrv_postgres [edit]
[-] rebuilduserssldb [edit]
[-] update_neighbor_netblocks [edit]
[-] disablefileprotect [edit]
[-] restartsrv_httpd [edit]
[-] uninstall_plugin [edit]
[-] buildnsdconf [edit]
[-] gather_update_log_stats [edit]
[-] rfc1912_zones.tar [edit]
[-] xfertool [edit]
[-] pkgacct [edit]
[-] edit_cpanelsync_exclude_list [edit]
[-] dnssec-cluster-keys [edit]
[-] chkmydns [edit]
[-] remove_dovecot_index_files [edit]
[-] ea4_fresh_install [edit]
[-] setupnameserver [edit]
[-] manage_mysql_profiles [edit]
[-] swapip [edit]
[-] process_site_templates [edit]
[-] verify_api_spec_files [edit]
[-] restartsrv_powerdns [edit]
[-] regenerate_tokens [edit]
[-] notify_expiring_certificates_on_linked_nodes [edit]
[-] adduser [edit]
[-] restartsrv_eximstats [edit]
[-] migrate_local_ini_to_php_ini [edit]
[-] safetybits.pl [edit]
[-] initacls [edit]
[-] chpass [edit]
[-] cpanel_initial_install [edit]
[-] cpuser_port_authority [edit]
[-] manage_greylisting [edit]
[-] patchfdsetsize [edit]
[-] cleanmsglog [edit]
[-] suspendacct [edit]
[-] install_tuxcare_els_php [edit]
[-] fixmailman [edit]
[-] secureit [edit]
[-] optimize_eximstats [edit]
[-] ipcheck [edit]
[-] disable_prelink [edit]
[-] cpan_config [edit]
[-] rebuilddnsconfig [edit]
[-] ensure_cpuser_file_ip [edit]
[-] securemysql [edit]
[-] ensure_conf_dir_crt_key [edit]
[-] configure_firewall_for_cpanel [edit]
[-] setupftpserver [edit]
[-] eximconfgen [edit]
[-] custom_backup_destination.pl.skeleton [edit]
[-] convert_maildir_to_mdbox [edit]
[-] rebuild_bandwidthdb_root_cache [edit]
[-] elevate-cpanel [edit]
[-] fix-web-vhost-configuration [edit]
[-] primary_virtual_host_migration [edit]
[-] ensure_vhost_includes [edit]
[-] purge_modsec_log [edit]
[-] restartsrv_cpgreylistd [edit]
[-] sync-mysql-users-from-grants [edit]
[-] update_known_proxy_ips [edit]
[-] activesync-invite-reply [edit]
[-] rescan_user_dovecot_fts [edit]
[-] sa-update_wrapper [edit]
[-] adddns [edit]
[-] whmlogin [edit]
[-] php_fpm_config [edit]
[-] shrink_modsec_ip_database [edit]
[-] updatedomainips [edit]
[-] restartsrv_chkservd [edit]
[-] auto-adjust-mysql-limits [edit]
[-] configure_rh_firewall_for_cpanel [edit]
[-] updateuserdatacache [edit]
[-] update_db_cache [edit]
[-] detect_env_capabilities [edit]
[-] locale_import [edit]
[-] modify_featurelist [edit]
[-] fix_innodb_tables [edit]
[-] postupcp.cloudlinux-linksafe.bak [edit]
[-] createacct [edit]
[-] migrate-pdns-conf [edit]
[-] ftpquotacheck [edit]
[-] updatesupportauthorizations [edit]
[-] reloadnsd [edit]
[-] cleanquotas [edit]
[-] dumpquotas [edit]
[-] forcelocaldomain [edit]
[-] uninstall_dovecot_fts [edit]
[-] buildpureftproot [edit]
[-] verify_pidfile [edit]
[-] xfer_rcube_schema_migrate.pl [edit]