ꦫꦣꦺꦤ꧀ꦄꦤ꧀ꦠꦱꦺꦤ

PATH: usr / share / aclocal

# intdiv0.m4 serial 6 (gettext-0.18.2)
dnl Copyright (C) 2002, 2007-2008, 2010-2016 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl From Bruno Haible.

AC_DEFUN([gt_INTDIV0],
[
  AC_REQUIRE([AC_PROG_CC])dnl
  AC_REQUIRE([AC_CANONICAL_HOST])dnl

AC_CACHE_CHECK([whether integer division by zero raises SIGFPE],
    gt_cv_int_divbyzero_sigfpe,
    [
      gt_cv_int_divbyzero_sigfpe=
changequote(,)dnl
      case "$host_os" in
        macos* | darwin[6-9]* | darwin[1-9][0-9]*)
          # On Mac OS X 10.2 or newer, just assume the same as when cross-
          # compiling. If we were to perform the real test, 1 Crash Report
          # dialog window would pop up.
          case "$host_cpu" in
            i[34567]86 | x86_64)
              gt_cv_int_divbyzero_sigfpe="guessing yes" ;;
          esac
          ;;
      esac
changequote([,])dnl
      if test -z "$gt_cv_int_divbyzero_sigfpe"; then
        AC_RUN_IFELSE(
          [AC_LANG_SOURCE([[
#include <stdlib.h>
#include <signal.h>

static void
sigfpe_handler (int sig)
{
  /* Exit with code 0 if SIGFPE, with code 1 if any other signal.  */
  _exit (sig != SIGFPE);
}

int x = 1;
int y = 0;
int z;
int nan;

int main ()
{
  signal (SIGFPE, sigfpe_handler);
/* IRIX and AIX (when "xlc -qcheck" is used) yield signal SIGTRAP.  */
#if (defined (__sgi) || defined (_AIX)) && defined (SIGTRAP)
  signal (SIGTRAP, sigfpe_handler);
#endif
/* Linux/SPARC yields signal SIGILL.  */
#if defined (__sparc__) && defined (__linux__)
  signal (SIGILL, sigfpe_handler);
#endif

z = x / y;
  nan = y / y;
  exit (2);
}
]])],
          [gt_cv_int_divbyzero_sigfpe=yes],
          [gt_cv_int_divbyzero_sigfpe=no],
          [
            # Guess based on the CPU.
changequote(,)dnl
            case "$host_cpu" in
              alpha* | i[34567]86 | x86_64 | m68k | s390*)
                gt_cv_int_divbyzero_sigfpe="guessing yes";;
              *)
                gt_cv_int_divbyzero_sigfpe="guessing no";;
            esac
changequote([,])dnl
          ])
      fi
    ])
  case "$gt_cv_int_divbyzero_sigfpe" in
    *yes) value=1;;
    *) value=0;;
  esac
  AC_DEFINE_UNQUOTED([INTDIV0_RAISES_SIGFPE], [$value],
    [Define if integer division by zero raises signal SIGFPE.])
])

[-] gpg-error.m4 [edit]
[-] inttypes_h.m4 [edit]
[-] ltsugar.m4 [edit]
[-] wint_t.m4 [edit]
[-] argz.m4 [edit]
[-] lcmessage.m4 [edit]
[-] ltdl.m4 [edit]
[-] autotrace.m4 [edit]
[-] intdiv0.m4 [edit]
[-] lib-link.m4 [edit]
[-] po.m4 [edit]
[+] ..
[-] printf-posix.m4 [edit]
[-] intl.m4 [edit]
[-] glib-gettext.m4 [edit]
[-] lt~obsolete.m4 [edit]
[-] intlmacosx.m4 [edit]
[-] intmax.m4 [edit]
[-] longlong.m4 [edit]
[-] intldir.m4 [edit]
[-] libxslt.m4 [edit]
[-] gsettings.m4 [edit]
[-] progtest.m4 [edit]
[-] inttypes-pri.m4 [edit]
[-] wchar_t.m4 [edit]
[-] codeset.m4 [edit]
[-] freetype2.m4 [edit]
[-] lib-prefix.m4 [edit]
[-] visibility.m4 [edit]
[-] xsize.m4 [edit]
[-] libgcrypt.m4 [edit]
[-] lock.m4 [edit]
[-] extern-inline.m4 [edit]
[-] ltversion.m4 [edit]
[-] glibc2.m4 [edit]
[-] stdint_h.m4 [edit]
[-] libxml.m4 [edit]
[-] pkg.m4 [edit]
[-] uintmax_t.m4 [edit]
[-] bison-i18n.m4 [edit]
[-] gettext.m4 [edit]
[-] iconv.m4 [edit]
[-] gtk-2.0.m4 [edit]
[-] lib-ld.m4 [edit]
[-] glib-2.0.m4 [edit]
[-] fontutil.m4 [edit]
[-] fcntl-o.m4 [edit]
[-] threadlib.m4 [edit]
[-] glibc21.m4 [edit]
[-] ltoptions.m4 [edit]
[-] nls.m4 [edit]
[-] libtool.m4 [edit]
[-] mysql.m4 [edit]
[-] size_max.m4 [edit]