ꦫꦣꦺꦤ꧀ꦄꦤ꧀ꦠꦱꦺꦤ

PATH: usr / share / vim / vim74 / ftplugin

" Vim filetype plugin file
" Language:	cobol
" Author:	Tim Pope <vimNOSPAM@tpope.info>
" $Id: cobol.vim,v 1.1 2007/05/05 17:24:38 vimboss Exp $

" Insert mode mappings: <C-T> <C-D> <Tab>
" Normal mode mappings: < > << >> [[ ]] [] ][
" Visual mode mappings: < >

if exists("b:did_ftplugin")
    finish
endif
let b:did_ftplugin = 1

let s:cpo_save = &cpo
set cpo&vim

setlocal commentstring=\ \ \ \ \ \ *%s
setlocal comments=:*
setlocal fo+=croqlt
setlocal expandtab
setlocal textwidth=72

" matchit support
if exists("loaded_matchit")
    let s:ordot = '\|\ze\.\%( \@=\|$\)'
    let b:match_ignorecase=1
    "let b:match_skip = 'getline(".") =~ "^.\\{6\\}[*/C]"'
    let b:match_words=
    \ '\$if\>:$else\>:\$endif\>,' .
    \ '[$-]\@<!\<if\>:\<\%(then\|else\)\>:\<end-if\>'.s:ordot.',' .
    \ '-\@<!\<perform\s\+\%(\d\+\s\+times\|until\|varying\|with\s\+test\)\>:\<end-perform\>'.s:ordot . ',' .
    \ '-\@<!\<\%(search\|evaluate\)\>:\<\%(when\)\>:\<end-\%(search\|evaluate\)\>' .s:ordot . ',' .
    \ '-\@<!\<\%(add\|compute\|divide\|multiply\|subtract\)\>\%(.*$\%$\|\%(\n\%(\%(\s*\|.\{6\}$[*/].*\n\)*\)\=\s*\%(not\s\+\)\=on\s\+size\s\+error\>\)\)\@=:\%(\<not\s\+\)\@<!\<\%(not\s\+\)\=on\s\+size\s\+error\>:\<end-\%(add\|compute\|divide\|multiply\|subtract\)\>' .s:ordot . ',' .
    \ '-\@<!\<\%(string\|unstring\|accept\|display\|call\)\>\%(.*$\%$\|\%(\n\%(\%(\s*\|.\{6\}$[*/].*\n\)*\)\=\s*\%(not\s\+\)\=on\s\+\%(overflow\|exception\)\>\)\)\@=:\%(\<not\s\+\)\@<!\<\%(not\s\+\)\=on\s\+\%(overflow\|exception\)\>:\<end-\%(string\|unstring\|accept\|display\|call\)\>' .s:ordot . ',' .
    \ '-\@<!\<\%(delete\|rewrite\|start\|write\|read\)\>\%(.*$\%$\|\%(\n\%(\%(\s*\|.\{6\}$[*/].*\n\)*\)\=\s*\%(invalid\s\+key\|at\s\+end\|no\s\+data\|at\s\+end-of-page\)\>\)\)\@=:\%(\<not\s\+\)\@<!\<\%(not\s\+\)\=\%(invalid\s\+key\|at\s\+end\|no\s\+data\|at\s\+end-of-page\)\>:\<end-\%(delete\|rewrite\|start\|write\|read\)\>' .s:ordot
endif

if has("gui_win32") && !exists("b:browsefilter")
  let b:browsefilter = "COBOL Source Files (*.cbl, *.cob)\t*.cbl;*.cob;*.lib\n".
		     \ "All Files (*.*)\t*.*\n"
endif

let b:undo_ftplugin = "setlocal com< cms< fo< et< tw<" .
            \ " | unlet! b:browsefilter b:match_words b:match_ignorecase b:match_skip"
if !exists("g:no_plugin_maps") && !exists("g:no_cobol_maps")
    let b:undo_ftplugin = b:undo_ftplugin .
            \ " | sil! exe 'nunmap <buffer> <'" .
            \ " | sil! exe 'nunmap <buffer> >'" .
            \ " | sil! exe 'nunmap <buffer> <<'" .
            \ " | sil! exe 'nunmap <buffer> >>'" .
            \ " | sil! exe 'vunmap <buffer> <'" .
            \ " | sil! exe 'vunmap <buffer> >'" .
            \ " | sil! exe 'iunmap <buffer> <C-D>'" .
            \ " | sil! exe 'iunmap <buffer> <C-T>'" .
            \ " | sil! exe 'iunmap <buffer> <Tab>'" .
            \ " | sil! exe 'nunmap <buffer> <Plug>Traditional'" .
            \ " | sil! exe 'nunmap <buffer> <Plug>Comment'" .
            \ " | sil! exe 'nunmap <buffer> <Plug>DeComment'" .
            \ " | sil! exe 'vunmap <buffer> <Plug>VisualTraditional'" .
            \ " | sil! exe 'vunmap <buffer> <Plug>VisualComment'" .
            \ " | sil! exe 'iunmap <buffer> <Plug>VisualDeComment'" .
            \ " | sil! exe 'unmap  <buffer> [['" .
            \ " | sil! exe 'unmap  <buffer> ]]'" .
            \ " | sil! exe 'unmap  <buffer> []'" .
            \ " | sil! exe 'unmap  <buffer> ]['"
endif

if !exists("g:no_plugin_maps") && !exists("g:no_cobol_maps")
    if version >= 700
        nnoremap <silent> <buffer> > :set opfunc=<SID>IncreaseFunc<CR>g@
        nnoremap <silent> <buffer> < :set opfunc=<SID>DecreaseFunc<CR>g@
    endif
    nnoremap <silent> <buffer> >> :call CobolIndentBlock(1)<CR>
    nnoremap <silent> <buffer> << :call CobolIndentBlock(-1)<CR>
    vnoremap <silent> <buffer> > :call CobolIndentBlock(v:count1)<CR>
    vnoremap <silent> <buffer> < :call CobolIndentBlock(-v:count1)<CR>
    inoremap <silent> <buffer> <C-T> <C-R>=<SID>IncreaseIndent()<CR><C-R>=<SID>RestoreShiftwidth()<CR>
    inoremap <silent> <buffer> <C-D> <C-R>=<SID>DecreaseIndent()<CR><C-R>=<SID>RestoreShiftwidth()<CR>
    if !maparg("<Tab>","i")
        inoremap <silent> <buffer> <Tab> <C-R>=<SID>Tab()<CR><C-R>=<SID>RestoreShiftwidth()<CR>
    endif
    noremap <silent> <buffer> [[ m':call search('\c^\%(\s*\<Bar>.\{6\}\s\+\)\zs[A-Za-z0-9-]\+\s\+\%(division\<Bar>section\)\s*\.','bW')<CR>
    noremap <silent> <buffer> ]] m':call search('\c^\%(\s*\<Bar>.\{6\}\s\+\)\zs[A-Za-z0-9-]\+\s\+\%(division\<Bar>section\)\.','W')<CR>
    noremap <silent> <buffer> [] m':call <SID>toend('b')<CR>
    noremap <silent> <buffer> ][ m':call <SID>toend('')<CR>
    " For EnhancedCommentify
    noremap <silent> <buffer> <Plug>Traditional      :call <SID>Comment('t')<CR>
    noremap <silent> <buffer> <Plug>Comment          :call <SID>Comment('c')<CR>
    noremap <silent> <buffer> <Plug>DeComment        :call <SID>Comment('u')<CR>
    noremap <silent> <buffer> <Plug>VisualTraditional :'<,'>call <SID>Comment('t')<CR>
    noremap <silent> <buffer> <Plug>VisualComment     :'<,'>call <SID>Comment('c')<CR>
    noremap <silent> <buffer> <Plug>VisualDeComment   :'<,'>call <SID>Comment('u')<CR>
endif

let &cpo = s:cpo_save
unlet s:cpo_save

if exists("g:did_cobol_ftplugin_functions")
    finish
endif
let g:did_cobol_ftplugin_functions = 1

function! s:repeat(str,count)
    let i = 0
    let ret = ""
    while i < a:count
        let ret = ret . a:str
        let i = i + 1
    endwhile
    return ret
endfunction

function! s:increase(...)
    let lnum = '.'
    let sw = &shiftwidth
    let i = a:0 ? a:1 : indent(lnum)
    if i >= 11
        return sw - (i - 11) % sw
    elseif i >= 7
        return 11-i
    elseif i == 6
        return 1
    else
        return 6-i
    endif
endfunction

function! s:decrease(...)
    let lnum = '.'
    let sw = &shiftwidth
    let i = indent(a:0 ? a:1 : lnum)
    if i >= 11 + sw
        return 1 + (i + 12) % sw
    elseif i > 11
        return i-11
    elseif i > 7
        return i-7
    elseif i == 7
        return 1
    else
        return i
    endif
endfunction

function! CobolIndentBlock(shift)
    let head = strpart(getline('.'),0,7)
    let tail = strpart(getline('.'),7)
    let indent = match(tail,'[^ ]')
    let sw = &shiftwidth
    let shift = a:shift
    if shift > 0
        if indent < 4
            let tail = s:repeat(" ",4-indent).tail
            let shift = shift - 1
        endif
        let tail = s:repeat(" ",shift*sw).tail
        let shift = 0
    elseif shift < 0
        if (indent-4) > -shift * sw
            let tail = strpart(tail,-shift * sw)
        elseif (indent-4) > (-shift-1) * sw
            let tail = strpart(tail,indent - 4)
        else
            let tail = strpart(tail,indent)
        endif
    endif
    call setline('.',head.tail)
endfunction

function! s:IncreaseFunc(type)
    '[,']call CobolIndentBlock(1)
endfunction

function! s:DecreaseFunc(type)
    '[,']call CobolIndentBlock(-1)
endfunction

function! s:IncreaseIndent()
    let c = "\<C-T>"
    if exists("*InsertCtrlTWrapper")
        let key = InsertCtrlTWrapper()
        if key != c
            return key
        endif
    endif
    let interval = s:increase()
    let b:cobol_shiftwidth = &shiftwidth
    let &shiftwidth = 1
    let lastchar = strpart(getline('.'),col('.')-2,1)
    if lastchar == '0' || lastchar == '^'
        return "\<BS>".lastchar.c
    else
        return s:repeat(c,interval)
    endif
endfunction

function! s:DecreaseIndent()
    let c = "\<C-D>"
    if exists("*InsertCtrlDWrapper")
        " I hack Ctrl-D to delete when not at the end of the line.
        let key = InsertCtrlDWrapper()
        if key != c
            return key
        endif
    endif
    let interval = s:decrease()
    let b:cobol_shiftwidth = &shiftwidth
    let &shiftwidth = 1
    return s:repeat(c,interval)
endfunction

function! s:RestoreShiftwidth()
    if exists("b:cobol_shiftwidth")
        let &shiftwidth=b:cobol_shiftwidth
        unlet b:cobol_shiftwidth
    endif
    return ""
endfunction

function! s:Tab()
    if (strpart(getline('.'),0,col('.')-1) =~ '^\s*$' && &sta)
        return s:IncreaseIndent()
    elseif &sts == &sw && &sts != 8 && &et
        return s:repeat(" ",s:increase(col('.')-1))
    else
        return "\<Tab>"
    endif
endfunction

function! s:Comment(arg)
    " For EnhancedCommentify
    let line = getline('.')
    if (line =~ '^.\{6\}[*/C]' || a:arg == 'c') && a:arg != 'u'
        let line = substitute(line,'^.\{6\}\zs.',' ','')
    else
        let line = substitute(line,'^.\{6\}\zs.','*','')
    endif
    call setline('.',line)
endfunction

function! s:toend(direction)
    let ignore = '^$\s*\|.\{6\}$\%([*/]\|\s*$\)'
    let keep = line('.')
    keepjumps +
    while line('.') < line('$') && getline('.') =~ ignore
        keepjumps +
    endwhile
    let res = search('\c^\%(\s*\|.\{6\}\s\+\)\zs[A-Za-z0-9-]\+\s\+\%(division\|section\)\s*\.',a:direction.'W')
    if a:direction != 'b' && !res
        let res = line('$')
        keepjumps $
    elseif res
        keepjumps -
    endif
    if res
        while line('.') > 1 && getline('.') =~ ignore
            keepjumps -
        endwhile
        if line('.') == 1 && getline('.') =~ ignore
            exe "keepjumps ".keep
        endif
    else
        exe "keepjumps ".keep
    endif
endfunction

[-] rpl.vim [edit]
[-] denyhosts.vim [edit]
[-] zimbu.vim [edit]
[-] nanorc.vim [edit]
[-] c.vim [edit]
[-] tt2html.vim [edit]
[-] group.vim [edit]
[-] muttrc.vim [edit]
[-] make.vim [edit]
[-] aspvbs.vim [edit]
[-] rnc.vim [edit]
[-] protocols.vim [edit]
[-] logtalk.vim [edit]
[-] postscr.vim [edit]
[-] gitrebase.vim [edit]
[-] eruby.vim [edit]
[-] udevrules.vim [edit]
[-] xs.vim [edit]
[-] ada.vim [edit]
[-] sql.vim [edit]
[-] liquid.vim [edit]
[-] mplayerconf.vim [edit]
[-] abap.vim [edit]
[-] mrxvtrc.vim [edit]
[-] xsd.vim [edit]
[-] quake.vim [edit]
[-] tex.vim [edit]
[-] xdefaults.vim [edit]
[-] aap.vim [edit]
[-] matlab.vim [edit]
[-] kconfig.vim [edit]
[-] bdf.vim [edit]
[-] ishd.vim [edit]
[-] calendar.vim [edit]
[-] gpg.vim [edit]
[-] gitcommit.vim [edit]
[-] cvsrc.vim [edit]
[-] libao.vim [edit]
[+] ..
[-] qf.vim [edit]
[-] cs.vim [edit]
[-] dtd.vim [edit]
[-] python.vim [edit]
[-] svg.vim [edit]
[-] changelog.vim [edit]
[-] sshconfig.vim [edit]
[-] man.vim [edit]
[-] screen.vim [edit]
[-] xmodmap.vim [edit]
[-] treetop.vim [edit]
[-] tcsh.vim [edit]
[-] setserial.vim [edit]
[-] elinks.vim [edit]
[-] xhtml.vim [edit]
[-] dircolors.vim [edit]
[-] manconf.vim [edit]
[-] passwd.vim [edit]
[-] gitsendemail.vim [edit]
[-] perl6.vim [edit]
[-] dosini.vim [edit]
[-] cucumber.vim [edit]
[-] hamster.vim [edit]
[-] verilog.vim [edit]
[-] java.vim [edit]
[-] reva.vim [edit]
[-] README.txt [edit]
[-] crm.vim [edit]
[-] loginaccess.vim [edit]
[-] updatedb.vim [edit]
[-] gitconfig.vim [edit]
[-] scss.vim [edit]
[-] pamconf.vim [edit]
[-] slpconf.vim [edit]
[-] tcl.vim [edit]
[-] plaintex.vim [edit]
[-] flexwiki.vim [edit]
[-] art.vim [edit]
[-] nsis.vim [edit]
[-] yaml.vim [edit]
[-] zsh.vim [edit]
[-] pascal.vim [edit]
[-] objc.vim [edit]
[-] pyrex.vim [edit]
[-] lprolog.vim [edit]
[-] services.vim [edit]
[-] occam.vim [edit]
[-] initex.vim [edit]
[-] automake.vim [edit]
[-] xml.vim [edit]
[-] fortran.vim [edit]
[-] sysctl.vim [edit]
[-] xslt.vim [edit]
[-] help.vim [edit]
[-] netrc.vim [edit]
[-] grub.vim [edit]
[-] csc.vim [edit]
[-] ch.vim [edit]
[-] msmessages.vim [edit]
[-] m4.vim [edit]
[-] diff.vim [edit]
[-] htmldjango.vim [edit]
[-] mailcap.vim [edit]
[-] csh.vim [edit]
[-] ant.vim [edit]
[-] erlang.vim [edit]
[-] debcontrol.vim [edit]
[-] racc.vim [edit]
[-] abaqus.vim [edit]
[-] slpspi.vim [edit]
[-] logcheck.vim [edit]
[-] vim.vim [edit]
[-] udevconf.vim [edit]
[-] vb.vim [edit]
[-] alsaconf.vim [edit]
[-] mp.vim [edit]
[-] git.vim [edit]
[-] vhdl.vim [edit]
[-] lftp.vim [edit]
[-] ocaml.vim [edit]
[-] cdrdaoconf.vim [edit]
[-] css.vim [edit]
[-] dosbatch.vim [edit]
[-] lua.vim [edit]
[-] sieve.vim [edit]
[-] debchangelog.vim [edit]
[-] perl.vim [edit]
[-] sensors.vim [edit]
[-] eterm.vim [edit]
[-] haml.vim [edit]
[-] falcon.vim [edit]
[-] dictconf.vim [edit]
[-] scheme.vim [edit]
[-] dictdconf.vim [edit]
[-] docbk.vim [edit]
[-] xinetd.vim [edit]
[-] kwt.vim [edit]
[-] framescript.vim [edit]
[-] rst.vim [edit]
[-] dtrace.vim [edit]
[-] ruby.vim [edit]
[-] conf.vim [edit]
[-] fvwm.vim [edit]
[-] btm.vim [edit]
[-] javascript.vim [edit]
[-] fetchmail.vim [edit]
[-] ld.vim [edit]
[-] markdown.vim [edit]
[-] mailaliases.vim [edit]
[-] php.vim [edit]
[-] xf86conf.vim [edit]
[-] context.vim [edit]
[-] sass.vim [edit]
[-] a2ps.vim [edit]
[-] gprof.vim [edit]
[-] prolog.vim [edit]
[-] haskell.vim [edit]
[-] indent.vim [edit]
[-] hostconf.vim [edit]
[-] modconf.vim [edit]
[-] udevperm.vim [edit]
[-] html.vim [edit]
[-] bst.vim [edit]
[-] config.vim [edit]
[-] lisp.vim [edit]
[-] hostsaccess.vim [edit]
[-] mail.vim [edit]
[-] cpp.vim [edit]
[-] limits.vim [edit]
[-] cobol.vim [edit]
[-] spec.vim [edit]
[-] mf.vim [edit]
[-] pdf.vim [edit]
[-] terminfo.vim [edit]
[-] logindefs.vim [edit]
[-] clojure.vim [edit]
[-] jsp.vim [edit]
[-] sudoers.vim [edit]
[-] slpreg.vim [edit]
[-] sh.vim [edit]
[-] sgml.vim [edit]
[-] arch.vim [edit]
[-] procmail.vim [edit]
[-] readline.vim [edit]
[-] pinfo.vim [edit]
[-] logtalk.dict [edit]